~ruther/guix-config

ref: ed53500b87f092ebbb4538afad43b70171b18ae4 guix-config/home/modules/ruther/home/themes.scm -rw-r--r-- 5.0 KiB
ed53500b — Rutherther feat: add wayland-display and wlr-services shepherd services 1 year, 4 months ago 
                                                                                
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136

(define-module (ruther home themes)
  #:use-module ((guix licenses) #:prefix license:)
  #:use-module (gnu packages)
  #:use-module (gnu packages gnome)
  #:use-module (gnu packages web)
  #:use-module (gnu packages inkscape)
  #:use-module (gnu packages xorg)
  #:use-module (guix packages)
  #:use-module (guix utils)
  #:use-module (guix build utils)
  #:use-module (guix gexp)
  #:use-module (guix build-system gnu)
  #:use-module (guix download)
  #:use-module (guix git-download)

  #:export (make-graphite-gtk-theme
            make-tela-circle-icon-theme
            make-catppuccin-cursors))

(define* (make-graphite-gtk-theme #:key
                              theme
                              (color "standard")
                              (size "standard"))
  (package
    (name (string-append "graphite-" theme "-" color "-" size "-theme"))
    (version "2024-07-15")
    (source
     (origin
       (method git-fetch)
       (uri (git-reference
             (url "https://github.com/vinceliuice/Graphite-gtk-theme")
             (commit version)))
       (sha256
        (base32 "1fmbfyf5j9mi31r84x8vb1z82jfg9cqcg27q7n579l65n3zybpck"))))
    (build-system gnu-build-system)
    (inputs
     (list gnome-themes-extra))
    (native-inputs
     (list sassc))
    (properties
     `((theme-name . ,(string-append "Graphite-" theme "-" (string-titlecase color)))))
    (arguments
     `(#:phases (modify-phases %standard-phases
                  (delete 'configure)
                  (delete 'build)
                  (delete 'check)
                  (replace 'install
                    (lambda* (#:key inputs outputs #:allow-other-keys)
                      (invoke
                       "bash"
                       "install.sh"
                       "-t" ,theme
                       "-c" ,color
                       "-d" (string-append (assoc-ref %outputs "out") "/share/themes")))))))
    (synopsis "Graphite gtk theme")
    (description "Graphite gtk theme")
    (home-page "https://github.com/vinceliuice/Graphite-gtk-theme")
    (license license:gpl3)))

(define* (make-tela-circle-icon-theme #:key (variant "standard"))
  (package
    (name (string-append "tela-circle-" variant "-icon-theme"))
    (version "2024-04-19")
    (source
     (origin
       (method git-fetch)
       (uri (git-reference
             (url "https://github.com/vinceliuice/Tela-circle-icon-theme")
             (commit version)))
       (sha256
        (base32 "1w7m6wqc205y5v3lrwd2a27df0hfhp3xv4sgz12kv5qih2g2dldy"))
       (snippet
        #~(begin (use-modules (guix build utils))
                 (substitute* "install.sh"
                   (("gtk-update-icon-cache.*") ""))))))
    (build-system gnu-build-system)
    (inputs
     (list gnome-themes-extra))
    (properties
     `((icon-theme-name . ,(string-append "Tela-circle-" variant))
       (dark-icon-theme-name . ,(string-append "Tela-circle-" variant "-dark"))
       (light-icon-theme-name . ,(string-append "Tela-circle-" variant "-light"))))
    (arguments
     `(#:phases (modify-phases %standard-phases
                  (delete 'configure)
                  (delete 'build)
                  (delete 'check)
                  (replace 'install
                    (lambda* (#:key inputs outputs #:allow-other-keys)
                      (invoke
                       "bash"
                       "install.sh"
                       "-c" ,variant
                       "-d" (string-append (assoc-ref %outputs "out") "/share/icons")))))))
    (synopsis "Tela icon theme")
    (description "Tela icon theme")
    (home-page "https://github.com/vinceliuice/Tela-circle-icon-theme")
    (license #f)))

(define* (make-catppuccin-cursors #:key flavor accent)
  (package
    (name (string-append "cattpuccin-cursors-" flavor "-" accent))
    (version "0.3.1")
    (source
     (origin
       (method git-fetch)
       (uri (git-reference
             (url "https://github.com/catppuccin/cursors")
             (commit (string-append "v" version))))
       (sha256
        (base32 "0pb393jlsrjfz8jhrgydhmv4hygf5wjs5jbc5m5628nixzlc7v0a"))))
    (build-system gnu-build-system)
    (native-inputs
     (list inkscape xcursorgen))
    (properties
     `((cursor-theme-name . ,(string-append "catppuccin-" flavor "-" accent "-cursors"))))
    (arguments
     `(#:phases (modify-phases %standard-phases
                  (delete 'configure)
                  (delete 'check)
                  (replace 'build
                    (lambda* _
                      (invoke
                       "bash"
                       "build"
                       "-f" ,flavor
                       "-a" ,accent)))
                  (replace 'install
                    (lambda* _
                      (copy-recursively
                       "dist"
                       (string-append (assoc-ref %outputs "out") "/share/icons")))))))
    (synopsis "Catppuccin cursors")
    (description "Catppuccin cursors")
    (home-page "https://github.com/catppuccin/cursors/tree/main")
    (license license:gpl2)))