~ruther/qmk_firmware

5a45627e17d8ed914b5cd2ac5c50d349c88d7d6b — Ryan 5 years ago 17d0f63 
Remove old setup scripts (#8811)
patch browse .tar.gz 
7 files changed, 0 insertions(+), 402 deletions(-)

M .gitignore
D util/1-setup-path-win.bat
D util/2-setup-environment-win.bat
D util/ELEVATE_LICENSE.md
D util/Win_Check.bat
D util/add-paths.bat
D util/elevate.exe

M .gitignore => .gitignore +0 -1
@@ 48,7 48,6 @@ doxygen/
*.iml
.browse.VC.db*
*.stackdump
util/Win_Check_Output.txt
# Let these ones be user specific, since we have so many different configurations
.vscode/c_cpp_properties.json
.vscode/launch.json


D util/1-setup-path-win.bat => util/1-setup-path-win.bat +0 -66
@@ 1,66 0,0 @@
@SETLOCAL ENABLEEXTENSIONS ENABLEDELAYEDEXPANSION
@ECHO OFF
SET CMDLINERUNSTR=%SystemRoot%\system32\cmd.exe

DEL script1.log > NUL 2>&1
DEL add-paths.log > NUL 2>&1
DEL add-paths-detail.log > NUL 2>&1
DEL UPDATE > NUL 2>&1

ELEVATE -wait add-paths.bat >> script1.log 2>&1

IF ERRORLEVEL 1 (
	ECHO You denied admin access. Rerun the script, and be sure to press the yes button this time.
) ELSE (
	TYPE add-paths.log 2> NUL
)
ECHO.

:: Branch to UpdateEnv if we need to update
IF EXIST UPDATE (
	DEL UPDATE
	GOTO UpdateEnv
)

GOTO ExitBatch

:: -----------------------------------------------------------------------------

:UpdateEnv
ECHO Making updated PATH go live . . .
REG delete HKCU\Environment /F /V TEMPVAR > NUL 2>&1
setx TEMPVAR 1 > NUL
REG delete HKCU\Environment /F /V TEMPVAR > NUL 2>&1
IF NOT !cmdcmdline! == !CMDLINERUNSTR! (CALL :KillExplorer)
GOTO ExitBatch

:: -----------------------------------------------------------------------------

:ExitBatch
ENDLOCAL
PAUSE
EXIT /b

:: -----------------------------------------------------------------------------

:KillExplorer
ECHO.
ECHO.
ECHO Your desktop will be restarted. 
ECHO.
ECHO All file explorer windows except for the one you launched this script from WILL BE CLOSED.
ECHO.
ECHO Press enter when ready, or close this window if you would rather do a full restart of your computer at a later time.
ECHO.
PAUSE
ping -n 5 127.0.0.1 > NUL 2>&1
ECHO Killing process Explorer.exe. . . 
ECHO.  
taskkill /f /im explorer.exe > NUL
ECHO.   
ECHO Your desktop is now loading. . . 
ECHO.   
ping -n 5 127.0.0.1 > NUL 2>&1
START explorer.exe
START explorer.exe %CD%
EXIT /b
\ No newline at end of file


D util/2-setup-environment-win.bat => util/2-setup-environment-win.bat +0 -72
@@ 1,72 0,0 @@
@SETLOCAL ENABLEEXTENSIONS ENABLEDELAYEDEXPANSION
@ECHO OFF

CD %~dp0

SET STARTINGDIR=%CD%
echo %STARTINGDIR%

:: Check for admin privilages
SETX /M test test > nul 2>&1
IF NOT ["%ERRORLEVEL%"]==["0"] (
	ELEVATE -wait 2-setup-environment-win.bat & goto :EOF
) 

DEL %STARTINGDIR%\environment-setup.log

:: Make sure path to MinGW exists - if so, CD to it
SET MINGWPATH="C:\MinGW\bin"
IF NOT EXIST !MINGWPATH! (ECHO Path not found: %MINGWPATH%. Did you install MinGW to the default location? && GOTO ExitBatch)
CD /D %MINGWPATH%

ECHO.
ECHO ------------------------------------------
ECHO Installing wget and unzip
ECHO ------------------------------------------
ECHO.
mingw-get install msys-wget-bin msys-unzip-bin 

MKDIR temp
CD temp

ECHO.
ECHO ------------------------------------------
ECHO Installing dfu-programmer.
ECHO ------------------------------------------
ECHO.
wget --no-check-certificate 'http://downloads.sourceforge.net/project/dfu-programmer/dfu-programmer/0.7.2/dfu-programmer-win-0.7.2.zip' >> %STARTINGDIR%\environment-setup.log
unzip -o dfu-programmer-win-0.7.2.zip >> %STARTINGDIR%\environment-setup.log
COPY dfu-programmer.exe .. >> %STARTINGDIR%\environment-setup.log

ECHO ------------------------------------------
ECHO Downloading driver
ECHO ------------------------------------------
wget --no-check-certificate http://downloads.sourceforge.net/project/libusb-win32/libusb-win32-releases/1.2.6.0/libusb-win32-bin-1.2.6.0.zip >> %STARTINGDIR%\environment-setup.log
unzip -o libusb-win32-bin-1.2.6.0.zip >> %STARTINGDIR%\environment-setup.log
COPY libusb-win32-bin-1.2.6.0\bin\x86\libusb0_x86.dll ../libusb0.dll >> %STARTINGDIR%\environment-setup.log

ECHO.
ECHO ------------------------------------------
ECHO Installing driver. Accept prompt.
ECHO ------------------------------------------
ECHO.
IF EXIST "%WinDir%\System32\PnPUtil.exe" (%WinDir%\System32\PnPUtil.exe -i -a dfu-prog-usb-1.2.2\atmel_usb_dfu.inf && GOTO PNPUTILFOUND)
IF EXIST "%WinDir%\Sysnative\PnPUtil.exe" (%WinDir%\Sysnative\PnPUtil.exe -i -a dfu-prog-usb-1.2.2\atmel_usb_dfu.inf && GOTO PNPUTILFOUND)

ECHO FAILED. Could not find PnPUtil.exe in "%WinDir%\System32" or "%WinDir%\Sysnative".

:PNPUTILFOUND

:: Wait then delete directory
ping -n 5 127.0.0.1 > NUL 2>&1
CD ..
RD /s /q temp

ECHO ------------------------------------------
ECHO Finished!

:ExitBatch
CD /D %STARTINGDIR%
ENDLOCAL
PAUSE
EXIT /b
\ No newline at end of file


D util/ELEVATE_LICENSE.md => util/ELEVATE_LICENSE.md +0 -25
@@ 1,25 0,0 @@
Elevate was downloaded from [here](https://jpassing.com/2007/12/08/launch-elevated-processes-from-the-command-line/).

### LICENSE

The MIT License (MIT)

Copyright (c) <year> <copyright holders>

Permission is hereby granted, free of charge, to any person obtaining a copy
 of this software and associated documentation files (the "Software"), to deal
 in the Software without restriction, including without limitation the rights
 to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
 copies of the Software, and to permit persons to whom the Software is
 furnished to do so, subject to the following conditions:

The above copyright notice and this permission notice shall be included in
 all copies or substantial portions of the Software.

THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
 IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
 FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
 AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
 LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
 OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN
 THE SOFTWARE.
\ No newline at end of file


D util/Win_Check.bat => util/Win_Check.bat +0 -208
@@ 1,208 0,0 @@
@setlocal ENABLEEXTENSIONS ENABLEDELAYEDEXPANSION
@echo OFF
set BAT_VERSION=v1.0
set REPORT_NAME=Win_Check_Output.txt

:: -----------------------------------------------------------------------------

cls

echo QMK Windows Check Output %BAT_VERSION%
echo QMK Windows Check Output %BAT_VERSION%.>%REPORT_NAME%

:: -----------------------------------------------------------------------------

set MINGW_BASE_DIR=C:\MinGW

set KEYMAP=atomic-pvc
set KEYMAP_CLEAN=atomic-pvc-clean

:: -----------------------------------------------------------------------------

if /I "%1" EQU VERBOSE (goto :Verbose_Make) else (goto :Normal_Make)

:Normal_Make
set MAKE_CMD_LEVEL_0=make -r -f Makefile COLOR=FALSE
set MAKE_CMD_LEVEL_1=make -r -f ../Makefile COLOR=FALSE
set MAKE_CMD_LEVEL_2=make -r -f ../../Makefile COLOR=FALSE
goto :Start_Report

:Verbose_Make
echo Verbose Mode
set MAKE_CMD_LEVEL_0=make -r -d -f Makefile COLOR=FALSE VERBOSE=TRUE
set MAKE_CMD_LEVEL_1=make -r -d -f ../Makefile COLOR=FALSE VERBOSE=TRUE
set MAKE_CMD_LEVEL_2=make -r -d -f ../../Makefile COLOR=FALSE VERBOSE=TRUE
goto :Start_Report

:Start_Report


:: -----------------------------------------------------------------------------

set HEADER=CURRENT DIRECTORY & call :ReportHeader

echo %CD%>>%REPORT_NAME% 2>&1

echo.>>%REPORT_NAME% 2>&1

:: -----------------------------------------------------------------------------

set HEADER=CURRENT PATHS & call :ReportHeader

for %%A in ("%path:;=";"%") do (echo %%~A>>%REPORT_NAME% 2>&1)

echo.>>%REPORT_NAME% 2>&1

:: -----------------------------------------------------------------------------

rem set HEADER=CURRENT ENVIRONMENTAL SETTINGS & call :ReportHeader

rem set>>%REPORT_NAME% 2>&1
rem echo.>>%REPORT_NAME% 2>&1

:: -----------------------------------------------------------------------------

set HEADER=KEY EXECUTABLE LOCATIONS - GENERAL & call :ReportHeader

set FILENAME=make.exe & set VERSION_CMD=--version & set VERSION_FIND="GNU Make" & call :ReportVersion
set FILENAME=git.exe & set VERSION_CMD=--version & set VERSION_FIND="git" & call :ReportVersion
set FILENAME=cmp.exe & set VERSION_CMD=--version & set VERSION_FIND="cmp" & call :ReportVersion

:: -----------------------------------------------------------------------------

set HEADER=EXECUTABLE LOCATIONS - AVR MCU COMPILERS & call :ReportHeader

set FILENAME=avr-gcc.exe & set VERSION_CMD=--version & set VERSION_FIND="avr" & call :ReportVersion
set FILENAME=avr-objcopy.exe & set VERSION_CMD=--version & set VERSION_FIND="GNU objcopy" & call :ReportVersion
set FILENAME=avr-objdump.exe & set VERSION_CMD=--version & set VERSION_FIND="GNU objdump" & call :ReportVersion
set FILENAME=avr-size.exe & set VERSION_CMD=--version & set VERSION_FIND="GNU size" & call :ReportVersion
set FILENAME=avr-ar.exe & set VERSION_CMD=--version & set VERSION_FIND="GNU ar" & call :ReportVersion
set FILENAME=avr-nm.exe & set VERSION_CMD=--version & set VERSION_FIND="GNU nm" & call :ReportVersion

:: -----------------------------------------------------------------------------

set HEADER=EXECUTABLE LOCATIONS - ARM MCU COMPILERS & call :ReportHeader

set FILENAME=arm-none-eabi-gcc.exe & set VERSION_CMD=--version & set VERSION_FIND="arm-none-eabi-gcc" & call :ReportVersion
set FILENAME=arm-none-eabi-objcopy.exe & set VERSION_CMD=--version & set VERSION_FIND="GNU objcopy" & call :ReportVersion
set FILENAME=arm-none-eabi-objdump.exe & set VERSION_CMD=--version & set VERSION_FIND="GNU objdump" & call :ReportVersion
set FILENAME=arm-none-eabi-size.exe & set VERSION_CMD=--version & set VERSION_FIND="GNU size" & call :ReportVersion
set FILENAME=arm-none-eabi-ar.exe & set VERSION_CMD=--version & set VERSION_FIND="GNU ar" & call :ReportVersion
set FILENAME=arm-none-eabi-nm.exe & set VERSION_CMD=--version & set VERSION_FIND="GNU nm" & call :ReportVersion

:: -----------------------------------------------------------------------------

set HEADER=EXECUTABLE LOCATIONS - NATIVE COMPILERS & call :ReportHeader

set FILENAME=gcc.exe & set VERSION_CMD=--version & set VERSION_FIND="gcc" & call :ReportVersion
set FILENAME=objcopy.exe & set VERSION_CMD=--version & set VERSION_FIND="GNU objcopy" & call :ReportVersion
set FILENAME=objdump.exe & set VERSION_CMD=--version & set VERSION_FIND="GNU objdump" & call :ReportVersion
set FILENAME=size.exe & set VERSION_CMD=--version & set VERSION_FIND="GNU size" & call :ReportVersion
set FILENAME=ar.exe & set VERSION_CMD=--version & set VERSION_FIND="GNU ar" & call :ReportVersion
set FILENAME=nm.exe & set VERSION_CMD=--version & set VERSION_FIND="GNU nm" & call :ReportVersion

:: -----------------------------------------------------------------------------

set HEADER=EXECUTABLE LOCATIONS - PROGRAMMERS & call :ReportHeader

set FILENAME=dfu-programmer.exe & set VERSION_CMD=--version & set VERSION_FIND="dfu" & call :ReportVersion
set FILENAME=batchisp.exe & set VERSION_CMD=-version & set VERSION_FIND="batchisp" & call :ReportVersion
set FILENAME=dfu-util.exe & call :Report
set FILENAME=teensy_loader_cli.exe & call :Report
set FILENAME=hid_bootloader_cli.exe & call :Report
set FILENAME=avrdude.exe & call :Report

:: -----------------------------------------------------------------------------

set HEADER=EXECUTABLE LOCATIONS - OPTIONAL & call :ReportHeader
set FILENAME=cppcheck.exe & call :Report
set FILENAME=doxygen.exe & call :Report
set FILENAME=gdb-config.exe & call :Report
set FILENAME=wget.exe & call :Report
set FILENAME=unzip.exe & call :Report

:: -----------------------------------------------------------------------------

set HEADER=MINGW CHECK - OPTIONAL & call :ReportHeader
if exist %MINGW_BASE_DIR% (echo Expected MinGW Base Dir = %MINGW_BASE_DIR%>>%REPORT_NAME% 2>&1) else (echo Expected MinGW Base Dir = %MINGW_BASE_DIR% - Not Found>>%REPORT_NAME% 2>&1)
echo.>>%REPORT_NAME% 2>&1
set FILENAME=mingw32-make.exe & set VERSION_CMD=--version & set VERSION_FIND="GNU Make" & call :ReportVersion
if exist %MINGW_BASE_DIR%\bin\make.exe (ECHO It is not recommended to have make.exe in mingw/bin.>>%REPORT_NAME% 2>&1 & echo.>>%REPORT_NAME% 2>&1)

:: -----------------------------------------------------------------------------

set HEADER=MAKE CHECK & call :ReportHeader
if exist Makefile (set MAKE_CMD=%MAKE_CMD_LEVEL_0% & goto MakeFound)
if exist ..\Makefile (set MAKE_CMD=%MAKE_CMD_LEVEL_1% & goto MakeFound)
if exist ..\..\Makefile (set MAKE_CMD=%MAKE_CMD_LEVEL_2% & goto MakeFound)

echo No Makfile Found.>>%REPORT_NAME% 2>&1
echo.>>%REPORT_NAME% 2>&1
echo ------------------------------------------------------------------------->>%REPORT_NAME% 2>&1

goto :ContinueAfterMake

:MakeFound
call :RunMake

:ContinueAfterMake
goto :ExitBatch

:ExitBatch
	echo Done!
	echo.
	rem type %REPORT_NAME%
	echo.
	echo See %REPORT_NAME% for the report.
	endlocal
exit /b

:: -----------------------------------------------------------------------------

:RunMake

	echo Makfile Found.>>%REPORT_NAME% 2>&1
	echo.>>%REPORT_NAME% 2>&1
	set HEADER=MAKE CLEAN & call :ReportHeader
	echo Make Command = %MAKE_CMD% %KEYMAP_CLEAN%>>%REPORT_NAME% 2>&1
	echo.>>%REPORT_NAME% 2>&1
	%MAKE_CMD% %KEYMAP_CLEAN%>>%REPORT_NAME% 2>&1
	set HEADER=MAKE & call :ReportHeader
	echo Make Command = %MAKE_CMD% %KEYMAP%>>%REPORT_NAME% 2>&1
	echo.>>%REPORT_NAME% 2>&1
	%MAKE_CMD% %KEYMAP%>>%REPORT_NAME% 2>&1
	echo ------------------------------------------------------------------------->>%REPORT_NAME% 2>&1
	echo.>>%REPORT_NAME% 2>&1
exit /b

:ReportHeader
	echo ------------------------------------------------------------------------->>%REPORT_NAME% 2>&1
	echo.>>%REPORT_NAME% 2>&1
	echo %HEADER%>>%REPORT_NAME% 2>&1
	echo.>>%REPORT_NAME% 2>&1
exit /b

:Report
	echo Filename = %FILENAME% >>%REPORT_NAME% 2>&1
	<nul set /p output="Location = " >>%REPORT_NAME% 2>&1
	where %FILENAME%  >>%REPORT_NAME% 2> NUL
	if ERRORLEVEL 1 (echo Not Found >>%REPORT_NAME% 2>&1 & goto :EndReport)

	:EndReport
	echo.>>%REPORT_NAME% 2>&1
	<nul set /p output="."
exit /b

:ReportVersion
	echo Filename = %FILENAME% >>%REPORT_NAME% 2>&1
	<nul set /p output="Location = " >>%REPORT_NAME% 2>&1
	where %FILENAME%  >>%REPORT_NAME% 2> NUL
	if ERRORLEVEL 1 (echo Not Found >>%REPORT_NAME% 2>&1 & goto :EndReportVersion)
	<nul set /p output ="Version  = " >>%REPORT_NAME% 2>&1

	(%FILENAME% %VERSION_CMD% | find %VERSION_FIND%) >>%REPORT_NAME% 2>&1

	:EndReportVersion
	echo.>>%REPORT_NAME% 2>&1
	<nul set /p output="."
exit /b
\ No newline at end of file


D util/add-paths.bat => util/add-paths.bat +0 -30
@@ 1,30 0,0 @@
@SETLOCAL ENABLEEXTENSIONS ENABLEDELAYEDEXPANSION
@ECHO off

SET NEWPATH1="C:\MinGW\msys\1.0\bin"
SET NEWPATH2="C:\MinGW\bin"

CD %~dp0

ECHO. > add-paths.log

CALL :AddPath %NEWPATH1%
CALL :AddPath %NEWPATH2%

EXIT /b

:AddPath <pathToAdd>
ECHO %PATH% | FINDSTR /C:"%~1" > nul
IF ERRORLEVEL 1 (
	 REG add "HKLM\SYSTEM\CurrentControlSet\Control\Session Manager\Environment" /f /v PATH /t REG_SZ /d "%PATH%;%~1" >> add-paths-detail.log
	IF ERRORLEVEL 0 (
		ECHO Adding   %1 . . . Success! >> add-paths.log
		SET "PATH=%PATH%;%~1"
		COPY NUL UPDATE
	) ELSE (
		ECHO Adding   %1 . . . FAILED. Run this script with administrator privileges. >> add-paths.log
	)	
) ELSE (
	ECHO Skipping %1 - Already in PATH >> add-paths.log
	)
EXIT /b
\ No newline at end of file


D util/elevate.exe => util/elevate.exe +0 -0